• Web sitemize destek olmak, Hazır Excel Dosyaları indirmek ve sitemizi reklamsız kullanmak için VIP Üyelik Satın alabilirsiniz.
    Hesabını VIP Üyeliğe Yükselt

Çözüldü Aylık Tablolardan Günlük Liste Oluşturma

Vurkan

Yeni Üye
Kullanıcı
Versiyon
  1. Excel 2016
Sürüm
  1. 64 bit
Dil
  1. Türkçe

Reputation:

Arkadaşlar merhaba. Ekli dosyamda AYLIK ve MESAİ isimli sayfalardan GÜNLÜK isimli sayfama isim listesi çekmek istiyorum.
Personelin Ay içindeki çalışmaları A, B ve C harfleriyle gösterilmiş.
Ayrıca MESAİ sayfasında da o gün mesaisi olan personeller gösterilmiş.
Ben Günlük isimli sayfama B1 hücresine yazdığım tarihe göre A, B ve C gurubu listelerini AYLIK ve MESAİ isimli sayfalardan almak istiyorum. Şimdiden teşekkürler.
 

Ekli dosyalar

  • SERVİS - Kopya.xlsm
    31.6 KB · Görüntüleme: 8
Çözüm
Eklediğim belgeye göre B3 hücresindeki formülü aşağıdaki şekilde ve dizi formülüne dönüştürerek uygulayın.
Formüldeki $C$1 kısmını $C$18 ve $C$35 olarak değiştirip B ve C grubunun ilk hücresine aynı şekilde uygulayıp aşağı doğru kopyalayın.

Dizi formülü uygulaması: formül hücreye yapıştırılır, doğrudan ENTER yerine CTRL ve SHIFT tuşları basılı durumdayken ENTER tuşuna basılır.

C#:
=EĞERHATA(KAYDIR(AYLIK!$H$1;KÜÇÜK(EĞER(KAYDIR(AYLIK!$H$2;2;GÜN($B$1);18;1)=$C$1;SATIR(AYLIK!$H$4:$H$18));$A3)-1;);"")

Vurkan

Yeni Üye
Kullanıcı
Versiyon
  1. Excel 2016
Sürüm
  1. 64 bit
Dil
  1. Türkçe

Reputation:

Arkadaşlar sorum ve sorunum hala güncel. Olumlu yada olumsuz bir cevap alamadım. Böyle bir formül oluşturulamaz mı acaba. İki ayrı sayfadan olamazsa sadece AYLIK sayfasından tarihe göre günlük sayfasına liste alınabilir mi acaba? Teşekkürler.
 

Ömer BARAN

Kurucu
Yönetici
Kurucu
Versiyon
  1. Excel 2013
Sürüm
  1. 32 bit
Dil
  1. Türkçe

Reputation:

Tablolar için ayırdığınız satır sayılarının (15 satır) yeterli olmama ihtimali vardır diye varsayıyorum.
Bu nedenle; sonuç tablolarını alt alta değil de yanyana 3 sütun grubu şeklinde konumlandırmalısınız.
 

Vurkan

Yeni Üye
Kullanıcı
Versiyon
  1. Excel 2016
Sürüm
  1. 64 bit
Dil
  1. Türkçe

Reputation:

Üstadım servis araçları 18 kişilik ancak hem pandemi döneminde olduğumuzdan hem de 3 vardiya mesai olduğundan genellikle 5 ile 10 kişi arasında değişiyor. Satır aralarını küçülterek gerekirse 18 kişilik yapılabilir. Saygılar.
 

52779

Forum Yönetimi
Yönetici
Site Yöneticisi
Versiyon
  1. Ofis 365
Sürüm
  1. 32 bit
Dil
  1. Türkçe

Reputation:

Selamlar,
Uzunca bir formülle
B3 hücresindeki formül
Kod:
=EĞERHATA(İNDİS(AYLIK!$H$4:$H$18;TOPLAMA(15;6;(SATIR(AYLIK!$H$4:$H$18)-SATIR(AYLIK!$H$4)+1)/(KAYDIR(AYLIK!$I$4;;KAÇINCI($B$1;AYLIK!$I$2:$AM$2;0)-1;SATIRSAY(AYLIK!$H$4:$H$18);1)=$C$1);SATIRSAY(B$3:B3)));EĞERHATA(İNDİS(MESAİ!$E$2:$E$30;TOPLAMA(15;6;(SATIR(MESAİ!$E$2:$E$30)-SATIR(MESAİ!$E$2)+1)/(MESAİ!$B$2:$B$30=$B$1)/(MESAİ!$F$2:$F$30=$C$1);SATIRSAY($B$3:B3)-TOPLA.ÇARPIM(--(KAYDIR(AYLIK!$I$4;;KAÇINCI($B$1;AYLIK!$I$2:$AM$2;0)-1;SATIRSAY(AYLIK!$H$4:$H$18);1)=$C$1))));""))
Sayfalarınızdaki referans alanları kullanılarak hazırlanan dokumanınız ektedir. İncelersiniz....
 

Ekli dosyalar

  • ExcelDestekSERVİS - Kopya.xlsm
    33.2 KB · Görüntüleme: 2

52779

Forum Yönetimi
Yönetici
Site Yöneticisi
Versiyon
  1. Ofis 365
Sürüm
  1. 32 bit
Dil
  1. Türkçe

Reputation:

Bir alternatif de
Listenin / listelerin uzayabilme ihtimali göz önüne alınarak, Ad Tanımlamaları ile Dinamik alanlar oluşturularak formüle edildi.
GÜNLÜK sayfanızdaki listeler alt alta değil de yan yana oluşturuldu.
Ad Tanımlamaları ile ilgili açıklamalar PERSONEL sayfasında yapıldı.

(İlk mesajımdaki formül, ad tanımlamaları kullanılarak revize edildi)

C3 hücresindeki formül
Kod:
=EĞERHATA(İNDİS(PersAy;TOPLAMA(15;6;SATIR(DOLAYLI("1:"&SATIRSAY(PersAy)))/(GrupAy=D$1);SATIRSAY(C$3:C3)));EĞERHATA(İNDİS(PersMesai;TOPLAMA(15;6;SATIR(DOLAYLI("1:"&SATIRSAY(PersMesai)))/(TrhMesai=$C$1)/(GrupMesai=D$1);SATIRSAY(C$3:C3)-TOPLA.ÇARPIM(--(GrupAy=D$1))));""))

Ad Tanımlamaları için Bkz. Formüller >>> Ad Yöneticisi

Dosya ektedir... İncelersiniz....
 

Ekli dosyalar

  • SERVİS - Kopya.xlsm
    36.3 KB · Görüntüleme: 3

Vurkan

Yeni Üye
Kullanıcı
Versiyon
  1. Excel 2016
Sürüm
  1. 64 bit
Dil
  1. Türkçe

Reputation:

Sayın 52779 ve Ömer BARAN üstadlarım. Sizlere çok zahmet verdim. Ellerinize sağlık. Çok teşekkür ediyorum.
Günlük sayfasını sadece AYLIK sayfasından alacak olsaydık Formülde nasıl bir değişiklik gerekirdi acaba?
 

Ömer BARAN

Kurucu
Yönetici
Kurucu
Versiyon
  1. Excel 2013
Sürüm
  1. 32 bit
Dil
  1. Türkçe

Reputation:

Eklediğim belgeye göre B3 hücresindeki formülü aşağıdaki şekilde ve dizi formülüne dönüştürerek uygulayın.
Formüldeki $C$1 kısmını $C$18 ve $C$35 olarak değiştirip B ve C grubunun ilk hücresine aynı şekilde uygulayıp aşağı doğru kopyalayın.

Dizi formülü uygulaması: formül hücreye yapıştırılır, doğrudan ENTER yerine CTRL ve SHIFT tuşları basılı durumdayken ENTER tuşuna basılır.

C#:
=EĞERHATA(KAYDIR(AYLIK!$H$1;KÜÇÜK(EĞER(KAYDIR(AYLIK!$H$2;2;GÜN($B$1);18;1)=$C$1;SATIR(AYLIK!$H$4:$H$18));$A3)-1;);"")
 
Çözüm

52779

Forum Yönetimi
Yönetici
Site Yöneticisi
Versiyon
  1. Ofis 365
Sürüm
  1. 32 bit
Dil
  1. Türkçe

Reputation:

Selamlar,

Günlük sayfasını sadece AYLIK sayfasından alacak olsaydık Formülde nasıl bir değişiklik gerekirdi acaba?

Formülün ilk kısmı AYLIK Sayfasından alınan veriler içindir. Yani
ilk mesajımdaki formül için
Kod:
=EĞERHATA(İNDİS(AYLIK!$H$4:$H$18;TOPLAMA(15;6;(SATIR(AYLIK!$H$4:$H$18)-SATIR(AYLIK!$H$4)+1)/(KAYDIR(AYLIK!$I$4;;KAÇINCI($B$1;AYLIK!$I$2:$AM$2;0)-1;SATIRSAY(AYLIK!$H$4:$H$18);1)=$C$1);SATIRSAY(B$3:B3)));"")
ikinci mesajımdaki formül için ise
Kod:
=EĞERHATA(İNDİS(PersAy;TOPLAMA(15;6;SATIR(DOLAYLI("1:"&SATIRSAY(PersAy)))/(GrupAy=D$1);SATIRSAY(C$3:C3)));"")
 
Üst