Netten Brüte 2023

Netten Brüte 2023 isimli yazımızda, Excel ile Netten Brüte maaş hesaplaması yapmak için gerekli adımlar anlatılmaktadır.

Hesaplamalarımız:

  • Kolay anlaşılması açısından Asgari Ücret değerleri ile yapılacaktır.
  • Normal SGK statüsünde çalışan kişileri kapsayan hesaplama yöntemine göre yapılacaktır.
  • Sadece Netten Brüte giden temel hesaplama kriterleri baz alınacaktır.

İlk olarak, hesaplamamızın başlıklarını tanımlayalım:

Netten Brüte Maaş Hesaplama Başlıkları​

  1. A1 hücresine Aylar yazın,
  2. B1 hücresine Net Ücret yazın,
  3. C1 hücresine Brüt Ücret yazın,
  4. D1 hücresine SGK Matrahı yazın,
  5. E1 hücresine SGK Primi yazın,
  6. F1 hücresine İŞSİZLİK Primi yazın,
  7. G1 hücresine Gelir Vergisi Matrahı yazın,
  8. H1 hücresine Kümülatif Gelir Vergisi Matrahı yazın,
  9. I1 hücresine Gelir Vergisi 1 yazın,
  10. J1 hücresine Gelir Vergisi 2 yazın,
  11. K1 hücresine Gelir Vergisi 3 yazın,
  12. L1 hücresine Gelir Vergisi 4 yazın,
  13. M1 hücresine Gelir Vergisi 5 yazın,
  14. N1 hücresine Toplam Gelir Vergisi yazın,
  15. O1 hücresine AÜ Gelir Vergisi Matrahı yazın,
  16. P1 hücresine Asgari Ücret Kümülatif Matrahı yazın,
  17. Q1 hücresine AÜGV1 yazın,
  18. R1 hücresine AÜGV2 yazın,
  19. S1 hücresine AÜGV3 yazın,
  20. T1 hücresine AÜGV4 yazın,
  21. U1 hücresine AÜGV5 yazın,
  22. V1 hücresine Toplam Asgari Ücret Gelir Vergisi yazın,
  23. W1 hücresine Kesilen Gelir Vergisi yazın,
  24. X1 hücresine Damga Vergisi Matrahı yazın,
  25. Y1 hücresine Damga Vergisi yazın,
  26. Z1 hücresine Net Hakediş yazın,

Böylece, Netten Brüte Maaş Hesaplaması için bize gerekli olan başlıkları oluşturduk.

Şimdi, başlıklarımızın altına yazmamız gereken formüllere geçelim.

Netten Brüte 2023 Kullanılan Formüller​

Ay Bilgisi​

İlk olarak, A2 hücresine Ocak, A3 hücresine Şubat yazılmalıdır ve A2:A3 aralığı seçilmelidir. Daha sonra, sağ alt köşeden tutup 12 satır aşağıya çekilecektir. Böylece, Excel 12 Ay’ın isimlerini otomatik olarak yazmaktadır. Dilerseniz, ayların numaralarını da yazabilirsiniz.

Net Ücret Bilgisi

B2:B13 aralığına istediğiniz net ücret girilmelidir. Biz örneğimizde, 8.506,80-TL’yi kullanacağız.

Brüt Ücret Bilgisi​

Brüt Ücret bilgisini bulmak için, C2 hücresine aşağıdaki formülü yazılmalıdır ve C13’e kadar kopyalanmalıdır.

=B2+E2+F2+W2+X2
DİKKAT! Netten brüte hesaplama yapılabilmesi için, Excel Seçeneklerinden “Yinelemeli Hesaplamayı Etkinleştir” seçeneği işaretlenmiş olmalıdır. Nasıl yapıldığı buradan öğrenebilirsiniz.

SGK Matrahı​

İlk iki bilgi, tamamen kullanıcılara dayalı ve istenilen şekilde girilen bilgi alanlarımızı oluşturmaktadır. Artık, Excel Formüllerini konuşturma işlemine başlıyoruz.

1. D2 hücresine aşağıdaki formülü yazıp, D7 hücresi de dahil olmak üzere aşağı doğru kopyalıyoruz.

=EĞER(C2>75060;75060;C2)

2. D8 hücresine aşağıdaki formülü yazıp, D13 hücresi de dahil olmak üzere aşağı doğru kopyalıyoruz.

=EĞER(C8>75060;75060;C8)

Böylece formüllerimiz ile yazdığımız brüt ücretin SGK Tavanından büyük olması kontrolünü sağlamış olduk.

SGK Primi​

SGK Primi hesaplaması için E2 hücresine aşağıdaki formülü yazıyoruz ve E13 hücresine kadar kopyalıyoruz.

=YUVARLA(D2*14%;2)

Bu formül bize çalışanın maaşından kesilen SGK Priminin rakamını verecektir.

İŞSİZLİK Primi​

İŞSİZLİK Primi hesaplaması için F2 hücresine aşağıdaki formülü yazıyoruz ve F13 hücresine kadar kopyalıyoruz.

=YUVARLA(D2*1%;2)

Bu formül bize çalışanın maaşından kesilen İŞSİZLİK Priminin rakamını verecektir.

Gelir Vergisi Matrahı​

Çalışanın Gelir Vergisi hesabını yapmak için, referans alınan Gelir Vergisi Matrahı formülü şu şekilde olmaktadır.

=C2-TOPLA(E2:F2)

Üstteki formülü, G2 hücresine yapıştırıp; G13 hücresine kadar kopyalamanız gerekmektedir.

Kümülatif Gelir Vergisi Matrahı​

Çalışanın Gelir Vergisi hesaplamasını yapmak için, referans alınan Kümülatif Gelir Vergisi Matrahı formülü şu şekilde olmaktadır.

=G2+EĞER(ESAYIYSA(H1);H1;0)

Üstteki formülü, H2 hücresine yapıştırıp; H13 hücresine kadar kopyalamanız gerekmektedir.

Gelir Vergisi 1​

Çalışanın maaşından kesilen %15 oranındaki vergi hesaplamasını yapmak için formül şu şekilde olmaktadır.

=EĞER(VE((H2-G2)>=0;(H2-G2)<=70000);EĞER(H2<=70000;G2;70000-(H2-G2))*0,15;EĞER((H2-G2)<0;EĞER(VE(H2>0;H2<=70000);(H2-0)*0,15;EĞER(H2>70000;(70000-0)*0,15;0));0))

Formül, I2 hücresine yapıştırılmalıdır ve I13 hücresine kadar kopyalanmalıdır.

Gelir Vergisi 2​

Çalışanın maaşından kesilen %20 oranındaki vergi hesaplamasını yapmak için formül şu şekilde olmaktadır.

=EĞER(VE((H2-G2)>=70000;(H2-G2)<=150000);EĞER(H2<=150000;G2;150000-(H2-G2))*0,2;EĞER((H2-G2)<70000;EĞER(VE(H2>70000;H2<=150000);(H2-70000)*0,2;EĞER(H2>150000;(150000-70000)*0,2;0));0))

Formül, J2 hücresine yapıştırılmalıdır ve J13 hücresine kadar kopyalanmalıdır.

Gelir Vergisi 3​

Çalışanın maaşından kesilen %27 oranındaki vergi hesaplamasını yapmak için formül şu şekilde olmaktadır.

=EĞER(VE((H2-G2)>=150000;(H2-G2)<=550000);EĞER(H2<=550000;G2;550000-(H2-G2))*0,27;EĞER((H2-G2)<150000;EĞER(VE(H2>150000;H2<=550000);(H2-150000)*0,27;EĞER(H2>550000;(550000-150000)*0,27;0));0))

Formül, K2 hücresine yapıştırılmalıdır ve K13 hücresine kadar kopyalanmalıdır.

Gelir Vergisi 4​

Çalışanın maaşından kesilen %35 oranındaki vergi hesaplamasını yapmak için formül şu şekilde olmaktadır.

=EĞER(VE((H2-G2)>=550000;(H2-G2)<=1900000);EĞER(H2<=1900000;G2;1900000-(H2-G2))*0,35;EĞER((H2-G2)<550000;EĞER(VE(H2>550000;H2<=1900000);(H2-550000)*0,35;EĞER(H2>1900000;(1900000-550000)*0,35;0));0))

Formül, L2 hücresine yapıştırılmalıdır ve L13 hücresine kadar kopyalanmalıdır.

Gelir Vergisi 5​

Çalışanın maaşından kesilen %40 oranındaki vergi hesaplamasını yapmak için formül şu şekilde olmaktadır.

=EĞER((H2-G2)>=1900000;G2*0,4;EĞER(H2>1900000;(H2-1900000)*0,4;0))

Formül, M2 hücresine yapıştırılmalıdır ve M13 hücresine kadar kopyalanmalıdır.

Toplam Gelir Vergisi​

Üstte 5 ayrı dilimde çalışanların Gelir Vergisi hesaplamasını yaptık. Toplam Gelir Vergisi alanını ise, aynı anda birden fazla vergi dilimine giren çalışanların ilgili ay’a ait gelir vergisi toplamının ne olduğunu görmek amacıyla oluşturduk. Bunun için N2 hücresine aşağıdaki formülü yazıp, N13 hücresine kadar kopyalamanız yeterli olacaktır.

=TOPLA(I2:M2)

Netten Brüte 2023 Asgari Ücret Parametreleri​

2022 yılında değişen Maaş Hesaplama algoritması ile hayatımıza Asgari Ücret parametreleri de girmiş oldu. Şimdi bu parametreleri küçük açıklamalar ve hesaplama formülleri ile öğretelim.

AÜ Gelir Vergisi Matrahı​

Asgari Ücret Gelir Vergisi Matrahı, çalışanın SGK Matrahının Asgari Ücreti geçip geçmemesine bağlı ve Asgari Ücret Gelir Vergisinin hesaplanması için gerekli olan alandır. Bu hesaplamayı yapmak için:

1. O2:O7 hücre aralığına aşağıdaki formülü kopyalıyoruz.

=EĞER(C2<8506,80;C2;8506,80)

2. O8:O13 hücre aralığına ise formülünüzü küçük bir değişim ile aşağıdaki gibi kopyalıyoruz.

=EĞER(C8<8506,80;C8;8506,80)

Böylece yılın iki ayrı dilimindeki net asgari ücret rakamlarını kontrol ettirerek, Asgari Ücret Gelir Vergisi Matrahı rakamı bulunmaktadır.

Asgari Ücret Kümülatif Matrahı​

Çalışanın Gelir Vergisi hesabını yapmak için, referans alınan Gelir Vergisi Matrahı formülü şu şekilde olmaktadır.

=O2+EĞER(ESAYIYSA(P1);P1;0)

Üstteki formülü, P2 hücresine yapıştırıp; P13 hücresine kadar kopyalamanız gerekmektedir.

AÜGV1​

Çalışanın maaşından kesilen %15 oranındaki vergi hesaplamasını yapmak için formül şu şekilde olmaktadır.

=EĞER(VE((P2-O2)>=0;(P2-O2)<=70000);EĞER(P2<=70000;O2;70000-(P2-O2))*0,15;EĞER((P2-O2)<0;EĞER(VE(P2>0;P2<=70000);(P2-0)*0,15;EĞER(P2>70000;(70000-0)*0,15;0));0))

Formül, Q2 hücresine yapıştırılmalıdır ve Q13 hücresine kadar kopyalanmalıdır.

AÜGV2​

Çalışanın maaşından kesilen %20 oranındaki vergi hesaplamasını yapmak için formül şu şekilde olmaktadır.

=EĞER(VE((P2-O2)>=70000;(P2-O2)<=150000);EĞER(P2<=150000;O2;150000-(P2-O2))*0,2;EĞER((P2-O2)<70000;EĞER(VE(P2>70000;P2<=150000);(P2-70000)*0,2;EĞER(P2>150000;(150000-70000)*0,2;0));0))

Formül, R2 hücresine yapıştırılmalıdır ve R13 hücresine kadar kopyalanmalıdır.

AÜGV3​

Çalışanın maaşından kesilen %27 oranındaki vergi hesaplamasını yapmak için formül şu şekilde olmaktadır.

=EĞER(VE((P2-O2)>=150000;(P2-O2)<=550000);EĞER(P2<=550000;O2;550000-(P2-O2))*0,27;EĞER((P2-O2)<150000;EĞER(VE(P2>150000;P2<=550000);(P2-150000)*0,27;EĞER(P2>550000;(550000-150000)*0,27;0));0))

Formül, S2 hücresine yapıştırılmalıdır ve S13 hücresine kadar kopyalanmalıdır.

AÜGV4​

Çalışanın maaşından kesilen %35 oranındaki vergi hesaplamasını yapmak için formül şu şekilde olmaktadır.

=EĞER(VE((P2-O2)>=550000;(P2-O2)<=1900000);EĞER(P2<=1900000;O2;1900000-(P2-O2))*0,35;EĞER((P2-O2)<550000;EĞER(VE(P2>550000;P2<=1900000);(P2-550000)*0,35;EĞER(P2>1900000;(1900000-550000)*0,35;0));0))

Formül, T2 hücresine yapıştırılmalıdır ve T13 hücresine kadar kopyalanmalıdır.

AÜGV5​

Çalışanın maaşından kesilen %40 oranındaki vergi hesaplamasını yapmak için formül şu şekilde olmaktadır.

=EĞER((P2-O2)>=1900000;O2*0,4;EĞER(P2>1900000;(P2-1900000)*0,4;0))

Formül, U2 hücresine yapıştırılmalıdır ve U13 hücresine kadar kopyalanmalıdır.

Netten Brüte 2023 Toplam Asgari Ücret Gelir Vergisi​

Üstte 5 ayrı dilimde çalışanların Asgari Ücret Gelir Vergisi hesaplamaları yapılmıştır. Toplam Asgari Ücret Gelir Vergisi alanını ise, aynı anda birden fazla vergi dilimine giren çalışanların ilgili ay’a ait gelir vergisi toplamının ne olduğunu görmek amacıyla oluşturduk. Bunun için V2 hücresine aşağıdaki formülü yazıp, V13 hücresine kadar kopyalamanız yeterli olacaktır.

=TOPLA(Q2:U2)

Kesilecen Gelir Vergisi​

Artık, bu aşamada çalışanın maaşından kesilen işleme konu Gelir Vergisinin hesaplanmasına geçebiliriz. Bunun için, W2 hücresine aşağıdaki formülü yazıp, W13 hücresine kadar çoğaltıyoruz.

=YUVARLA(EĞER(N2-V2<=0;0;N2-V2);2)

Damga Vergisi Matrahı​

2022 yılının değişen maaş algoritmalarının etkilediği bir diğer husus ise Damga Vergisi oldu. Çalışanların maaşlarından Brüt Asgari Ücret kadar rakam damga vergisi hesaplamasından muaf edilmektedir. Böylece, Damga Vergisi hesaplamasını yapabilmemiz için gerekli olan Damga Vergisi Matrahı hesabını şu şekilde yapmaktayız.

1. X2 hücresine aşağıdaki formülü yazıyoruz ve X7 hücresi de dahil olmak üzere aşağı doğru kopyalıyoruz.

=EĞER(C2<=0;10008;C2-10008)

2. Y8 hücresine aşağıdaki formülü yazıyoruz ve X13 hücresi de dahil olmak üzere aşağı doğru kopyalıyoruz.

=EĞER(C8<=0;10008;C8-10008)

Damga Vergisi​

Çalışanın maaşından kesmemiz gereken Damga Vergisini hesaplamak için Y2 hücresine aşağıdaki formülü yazıyoruz ve Y13 hücresine kadar yapıştırıyoruz.

=YUVARLA(X2*0,759%;2)

Net Hakediş​

Ve artık noktayı koyma zamanı…Adım adım hesaplamalarımız neticesinde, Brüt Ücretimizden kesilen toplam 4 ana kalem vergisini düşerek çalışanın eline geçecek olan Net Hakediş rakamını bulunmalıdır. Yani, Z2 hücresine aşağıdaki formülü yazılmalıdır ve Z13 hücresine kadar kopyalanmalıdır.

=C2-E2-F2-W2-Y2

Netten Brüte 2023 Sonuç​

Artık, siz de kolayca bu formülleri kullanarak temel düzeyde bir maaş hesaplamasının nasıl yapıldığını öğrenebilirsiniz. Bu hesaplamadaki formüller, maaş hesabının en zor aşamalarından biri olan Gelir Vergisi hesaplamalarını da sorunsuzca yapmanızı sağlayacaktır.

Eğer, Excel formüllerine biraz aşinaysanız; Gelir Vergisi hesabının nasıl yapıldığının mantığını da rahatça anlayabilirsiniz. Dilerseniz, Brütten Nete hesaplama makalemizi de inceleyebilirsiniz.

Daha Fazla Göster

4 Yorum

  1. MERHABA FORMÜLLERİ KOPYLADIKTAN SONRA NETİ DEĞİŞTİRDİĞİMDE RAKAMLAR UZAYIP GİDİYOR HÜCEYE HER TIKLADIĞIMDA RAKAMLAR DEĞİŞİYOR NEDENİ NEDİR?

  2. Merhaba,

    Makalemizde yazılı olanlar tek tek denenerek yazılmıştır. Sizdeki etkisinin nedenini, üzerinde çalıştığınız görmeden bilmek çok mümkün değildir. Sadece aklıma gelen, “Döngüsel Başvuru” için gerekli ayarı yapmamış olabilmenizdir. Yazının, “Brüt Ücret Bilgisi​” başlığının hemen altında bu uyarı arka planı sarı renkli olacak şekilde eklenmiştir.

  3. Merhaba,
    Yinelenen formülü açtım. hepsini doğru yazdım. Ancak tüm formüllü hücrelerde değer hatası veriyor.
    Neden olabilir
    Şimdiden teşekkürler

Bir yanıt yazın

E-posta adresiniz yayınlanmayacak. Gerekli alanlar * ile işaretlenmişlerdir

Başa dön tuşu